setup_windows_2/app/install_greenshot.cmd

:: ------------------------------------------------------------
:: Installationsroutine
:: ------------------------------------------------------------

:: --- Option: Download in ein temporäres Verzeichnis
:: --- Kann für z.B. für GLPI abgeschaltet werden
set SAVEPATH=%SYSTEMDRIVE%\TEMP\install
MKDIR %SAVEPATH% 2> nul & CD /D %SAVEPATH%

:: --- Download Basis-URL, Dateiname und TEMP-Verzeichnis
:: https://github.com/greenshot/greenshot/releases/latest 
set VERS=1.3.304
set BASEURL=https://github.com/greenshot/greenshot/releases/download/v%VERS%
set PROG=Greenshot-INSTALLER-%VERS%-RELEASE.exe

:: --- Lade Datei herunter
echo    Starte Download.
  curl -kLSsf %BASEURL%/%PROG% -o %SAVEPATH%\%PROG%
if %ERRORLEVEL% EQU 0 (echo    Download OK! ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)

:: --- Schalte Win11 Snipping tool ab:
echo    Modifiziere Registry.
  REG add  "HKU\.DEFAULT\Control Panel\Keyboard" /t REG_SZ /v PrintScreenKeyForSnippingEnabled /d 0 /F
if %ERRORLEVEL% EQU 0 (echo    OK! ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)
  REG add  "HKCU\Control Panel\Keyboard" /t REG_SZ /v PrintScreenKeyForSnippingEnabled /d 0 /F
if %ERRORLEVEL% EQU 0 (echo    OK! ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)

:: --- Silent-Installation des Programms:
echo    Erstelle Konfiguration.
(
echo [Setup]
echo Lang=de
echo Dir=
echo Group=Greenshot
echo NoIcons=0
echo Tasks=
) > greenshot.inf

:: --- Silent-Installation des Programms:
echo    Starte Installation.
  %PROG% /ALLUSERS /NORESTART /VERYSILENT /SUPPRESSMSGBOXES /SP- /LOADINF=greenshot.inf
if %ERRORLEVEL% EQU 0 (echo    Installation OK! ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)