setup_windows_2/install.cmd

@echo off
:: ------------------------------------------------------------
:: Installer
::
:: Aufruf mit: install.cmd [app|script] <ProgrammName>
::
:: ------------------------------------------------------------

:: --- Erstelle und betrete Downloadverzeichnis
set SAVEPATH=%SYSTEMDRIVE%\TEMP\install
MKDIR %SAVEPATH% 2> nul & CD /D %SAVEPATH%

:: --- Basis-URL des Git-Repository
set GITHOST=https://support.ostrachhelp.de
set GITUSER=OstrachHELP
set GITREPO=setup_windows_2
set GITURL=%GITHOST%/%GITUSER%/%GITREPO%/raw/branch/main

:: --- Optionen für curl
set CURLOPT=-kLSsf -A "Mozilla/5.0 (Windows NT 10.0; Win64; x64)" 

:: --- wird install ohne App-Namen gestartet werden nur die globalen Variablen gesetzt
if "%1"=="" goto END
if "%1"=="app" goto INSTALL
if "%1"=="script" goto SCRIPT
GOTO END

:: --- Übernimmt die globalen Variablen und installiert die gewünschte App
:INSTALL
set APPNAME=%2
echo ------------- Installiere App: %APPNAME% ----------------------------------------
curl.exe %CURLOPT% -O %GITURL%/app/install_%APPNAME%.cmd & call install_%APPNAME%.cmd
IF %ERRORLEVEL% NEQ 0 ( 
   echo    Die Installation hat einen Fehler gemeldet.
)
Goto END

:: --- Übernimmt die globalen Variablen und installiert das gewünschte script
:SCRIPT
set APPNAME=%2
echo ------------- Starte Script: %APPNAME% ----------------------------------------
curl.exe %CURLOPT% -O %GITURL%/scripts/script_%APPNAME%.cmd & call script_%APPNAME%.cmd
IF %ERRORLEVEL% NEQ 0 ( 
   echo    Das Script hat einen Fehler gemeldet.
)
Goto END

:END
set SAVEPATH=%SYSTEMDRIVE%\TEMP\install & CD /D %SAVEPATH%