:: ------------------------------------------------------------
:: Installationsroutine
:: ------------------------------------------------------------

:: --- Option: Download in ein temporäres Verzeichnis
:: --- Kann für z.B. für GLPI abgeschaltet werden
set SAVEPATH=%SYSTEMDRIVE%\TEMP\install
MKDIR %SAVEPATH% 2> nul & CD /D %SAVEPATH%

:: --- Download Basis-URL, Dateiname und TEMP-Verzeichnis
set VERSION=26.2.4
set ARCH1=x86_64
set ARCH2=x86-64
set BASEURL=https://ftp.gwdg.de/pub/tdf/libreoffice/stable/%VERSION%/win/%ARCH1%
set PROG=LibreOffice_%VERSION%_Win_%ARCH2%.msi
set HLPR=LibreOffice_%VERSION%_Win_%ARCH2%_helppack_de.msi

:: --- Lade Installationsdatei herunter
echo    Starte Download Installer.
  curl -kLSsf %BASEURL%/%PROG% -o %SAVEPATH%\%PROG%
if %ERRORLEVEL% EQU 0 (echo    Download OK! ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)

:: --- Lade Hilfepack herunter
echo    Starte Download Hilfepack DE.
  curl -kLSsf %BASEURL%/%HLPR% -o %SAVEPATH%\%HLPR%
if %ERRORLEVEL% EQU 0 (echo    Download OK! ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)

:: --- Silent-Installation des Programms:
echo    Starte Installation.
  msiexec /i %PROG% /qn /norestart PRODUCTLANGUAGE=1031 LANGUAGE=1031 RebootYesNo=No QUICKSTART=0 UI_LANGS=de ADDLOCAL=ALL /l %SAVEPATH%\%PROG%.log
if %ERRORLEVEL% EQU 0 (echo    Installation OK! 
) else ( 
  if %ERRORLEVEL% EQU 3010 (echo    Neustart erforderlich!
  ) else (
  echo    Fehler %ERRORLEVEL% ist aufgetreten!
  )
)

echo    Starte Installation Hilfepack.
  msiexec /i %HLPR% /qn /norestart 
if %ERRORLEVEL% EQU 0 (echo    Installation OK! ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)