:: ------------------------------------------------------------
:: Installationsroutine
:: ------------------------------------------------------------

:: --- Option: Download in ein temporäres Verzeichnis
:: --- Kann für z.B. für GLPI abgeschaltet werden
set SAVEPATH=%SYSTEMDRIVE%\TEMP\install
MKDIR %SAVEPATH% 2> nul & CD /D %SAVEPATH%

:: --- Download Basis-URL, Dateiname und TEMP-Verzeichnis
:: https://www.microsip.org/downloads
set VERS=3.22.3
set BASEURL=https://www.microsip.org/download/MicroSIP-%VERS%.zip?1
set PROG=MicroSIP-%VERS%.zip

:: --- Lade Datei herunter
echo    Starte Download Version %VERS%.
  curl -kLSsf %BASEURL%/%PROG% -o %SAVEPATH%\%PROG%
if %ERRORLEVEL% EQU 0 (echo    Download OK! ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)

:: --- Unzipping....
echo    Entzippen.
  powershell.exe "& {Expand-Archive %PROG% -DestinationPath %SAVEPATH%\MSIP}"
if %ERRORLEVEL% EQU 0 (echo    Entzippen OK! ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)

:: --- Silent-Installation des Programms:
echo    Starte Installation.

MKDIR "%Programfiles(x86)%\MicroSIP"
COPY %SAVEPATH%\MSIP\*.* "%Programfiles(x86)%\MicroSIP\"
if %ERRORLEVEL% EQU 0 (echo    Kopieren der Dateien OK. ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)

:: --- Verknüpfung
set VBS=link.vbs
echo Set oWS = WScript.CreateObject("WScript.Shell")                >%VBS%
echo sLinkFile = "C:\Users\Public\Desktop\MicroSIP.lnk"             >>%VBS%
echo Set oLink = oWS.CreateShortcut(sLinkFile)                      >>%VBS%
echo oLink.TargetPath = "%Programfiles(x86)%\MicroSIP\microsip.exe" >>%VBS%
echo oLink.Save                                                     >>%VBS%

cscript /nologo %VBS%
if %ERRORLEVEL% EQU 0 (echo    Einrichten OK. ) else ( echo    Fehler %ERRORLEVEL% ist aufgetreten!)

:: MKLINK C:\Users\Public\Desktop\MicroSIP "%Programfiles(x86)%\MicroSIP\microsip.exe"